Startup/Exit VBScripts to merge .reg files, launch programs, and kill processes

I've been using the fabulous XrX PortableApps Menu Mod (I hope the additional features will eventually make it to the official version). I have been using the startup/exit functionality as well as the ability to execute VBScripts. I have some custom programs that require writing to the registry, so I wrote a bit of VBScript code to handle this. I created a directory in the PortableApps folder called Scripts and placed two .vbs files: start.vbs and exit.vbs. Using the XrX PortableApps Menu Mod I can execute them when the menu starts/exits. My startup script looks something like this:

Function launch(program)
  Set objShell = CreateObject("WScript.Shell")
  objShell.Run program
  set objShell = Nothing
End Function

Function reg(regpath)
  launch "regedit /s " & regpath
End Function

'Cycle through all of the PortableApps and search for install.reg files
Set fso = CreateObject("Scripting.FileSystemObject")
Set AppsFolders = fso.GetFolder("..")
For Each App In AppsFolders.Subfolders
  For Each File in App.Files
    If File.Name = "install.reg" Then reg File.Path
  Next
Next
Set AppsFolders = Nothing
Set fso = Nothing

'Start any stuff that needs to be launched
launch "..\MyEntunnel\myentunnel.exe"
launch "..\PidginPortable\PidginPortable.exe"

The launch function can be used to launch any custom programs (on start up I run MyEntunnel and Pidgin). There is a loop that goes through all of the app folders and looks for a file called install.reg. If it finds it, it will merge it with the registry. My exit script looks something like this:

Function kill(taskname)
  Set objWMIService = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\cimv2")
  Set colProcessList = objWMIService.ExecQuery ("SELECT * FROM Win32_Process WHERE Name = '" & taskname & "'")
  For Each objProcess in colProcessList
    objProcess.Terminate()
  Next
  Set objWMIService = Nothing
  Set colProcessList = Nothing
End Function

Function launch(program)
  Set objShell = CreateObject("WScript.Shell")
  objShell.Run program
  set objShell = Nothing
End Function

Function reg(regpath)
  launch "regedit /s " & regpath
End Function

'Kill any stuff that probably needs to die
kill "myentunnel.exe"
kill "plink.exe"
kill "pidgin.exe"

'Cycle through all of the PortableApps and search for uninstall.reg files
Set fso = CreateObject("Scripting.FileSystemObject")
Set AppsFolders = fso.GetFolder("..")
For Each App In AppsFolders.Subfolders
  For Each File in App.Files
    If File.Name = "uninstall.reg" Then reg File.Path
  Next
Next
Set AppsFolders = Nothing
Set fso = Nothing

First the script kills some processes that may still be running. Then, similar to the start.vbs, it cycles through all of the app folders searching for .reg files. However, it searches for files named uninstall.reg and merges them with the registry. Another thing I was thinking of doing to automate things a bit further for the exit script, is to scan all of the app folders for exe files and kill them if they are running. Please feel free to use the code and if you have any improvements to make, please share them here. Enjoy!