Batch file launcher in assembler

As promised here is the code for the program that launches an external batch file, followed by the test batch file.

I've tried to comment copiously so as to indicate what going on. This is very low level stuff, so even thought there are a lot of lines it compiles at 332 bytes.

I posted this because it comes close to what you did in MASM32 and would be of interest to you to compare. This one works and just needs some polishing up.

It is, however NOT the one that is giving me trouble and is the reason for my original post. Before posting that listing, however, I'm going to work with it a little bit more. I got a couple of ideas from our discussion that I want to try out first.

We'll see how that works out. Thanks for your help thus far!

Here's the listings:

-----------------  RUNBATCH  CODE ---------------------------

;;;;;;;; RUNBATCH
                    ;WARNING!!! THIS IS NOT A FINISHED PRODUCT!
                    ;
                    ;A routine to run a child process.
                    ;Done as a "proof of concept", not as a working program.
                    ;Uses INT2Eh to run the child process
                    ;invokes a copy of %COMSPEC% to execute the
                    ;data in the calling routine command tail.
                    ;NOTE: to work properly in winXP, the batch file
                    ;  executed must determine if the OS is WinXP
                    ;  and if so call CMD.EXE /C to execute another
                    ;  iteration of itself.
                    ;  The reason is that this routine returns
                    ;  COMMAND.COM as the COMSPEC value even though
                    ;  the correct value is CMD.EXE.  If this were
                    ;  an actual working program the identification of
                    ;  OS would be done here instead of the batch file.
         org   100h
;change memory allocation        ;make memory available for child process
         mov   ah, 4Ah
         mov   bx, offset endpgm
         shr   bx                ;change to paragraphs
         shr   bx                ;by dividing by 16 (dec)
         shr   bx                
         shr   bx
         inc   bx
         int   21h
;
;setup prog name (COMSPEC) by looking in environment block for COMSPEC=
         mov   ES, [2Ch]
         mov   DI, 0               ;look in environment segment
cmploop
         mov   SI, offset DblZer   ;look for End Of Environment marker 
         mov   cx, 2
         push  DI
         repe
         cmpsb
         pop   DI
         je    NF                  ;EOE reached w/ no match for COMSPEC.
                                   ;Failed. End search.

         mov   SI, offset comspec  ;look for COMSPEC
         mov   cx, 8
         push  DI
         repe
         cmpsb
         pop   DI
         je    found
contsch
         inc   DI
         jmp   cmploop

NF    
         ;if COMSPEC not found
         mov   ah, 09h
         mov   dx, offset NoComMsg
         int   21h
         mov   al, 2
         jmp   EXIT
found                       ;COMSPEC found in environment block
         cmp   DI, 0
         je    skipzck
         cmp   byte [DI-1], 0
         jne   contsch      ;not beg of arg. must be x..COMSPEC=
                            ;resume search

skipzck                     ;retrieve %COMSPEC% value
         push  ES           ;point DS to environment, ES to local
         push  DS
         pop   ES
         pop   DS
         xchg  DI,SI
         add   SI, 8
         mov   DI, offset progname
         mov   cx, 0
mov_val                             ;retrieve value for COMSPEC
         cmp   byte [SI], 0
         je    end_mov_val          ;and move to "progname"
         movsb
         inc   cx
         jmp   mov_val
end_mov_val
         push  ES                   ;restore ES to local value
         pop   DS 
;
;setup cmdtail
         xor   cx, cx               ;move calling routine cmd tail to
         mov   cl, [80h]            ;area for child process cmd tail
         add   cx, 1
         mov   SI, 81h
                          ;DI = value for offset cmdtail
         repnz
         movsb
         mov   cx, DI,
         sub   cx, offset cmdLINE
         dec   cx
         mov   cmdLine, cl
;
         ;EXEC the program
EXEC
         mov   SI, offset cmdline
         push  CS
         pop   DS            ;make sure DS points to Code Segment 
         int   2Eh
                             ;if any code follows betwwen INT 2E and "EXIT"
                             ;must add coding to save and restore
                             ;registers, SS,SP, DS,ES, ax,bx,cx,dx SI,DI.

         ;(this is where the "delete file" code would go)

EXIT     mov   ah, 4Ch       ;exit with return code. 
         int   21h
;
         db    'Begin data area',0         ;marker for beginning data area
;
comspec  db    'COMSPEC=',0                ;search argument for COMSPEC
dblzer   db    0,0                         ;END marker for environment area
NoComMsg db    '"COMSPEC" not found!', 24h        
         db    'progname follows',0
cmdline  db    0                           ;command tail for child process
progname ds    7Fh, 0                      ;%COMSPEC% value
endpgm   dw    offset endpgm               ;marker for EOP

---------------- END RUNBATCH ---------------------------------------------

Begin listing of NTEMP2.BAT:  Test file for above

@echo off
REM for testing to verify that it's loaded and running

if NOT %1!==! goto %1
if NOT %OS%!==Windows_NT! goto STARTBAT
   CMD /C %0 STARTBAT
   goto EXIT

:STARTBAT
@echo off
prompt Running %0$_$P$G
echo   Running %0 %1
echo COMSPEC=%COMSPEC%
rem see if long file name is recognized.
C:
CD "C:\Program Files"
CD
pause
rem before running place a CD to original directory on the next line
rem CD (return to original directory, don't forget remove the "rem"!)
:EXIT