IMPROVED: Howto: Safely remove USB Drive from batch file

the device string is the hardware ID for the device, so it wont change.

and I forgot to delete devcon.exe...oops.

I've just figured out how to get it to run, with a nice autorun.inf file (won't automatically launch but at least it pops up a menu and you just have to hit enter), and no dos windows appearing. Here's what I have:

Directory structure:

\autorun.inf
\Programs\pstart.exe
\Programs\devcon.exe
\Programs\startmenu.bat
\Programs\startmenu.vbs
\Programs\remove.bat


Autorun.inf:

[autorun]
shellexecute=Programs\startmenu.vbs
icon=Programs\PStart.exe
action=Launch PStart Menu


Startmenu.bat:

\programs\pstart.exe
ping -n 2 127.0.0.1
copy \programs\devcon.exe %temp%
copy \programs\remove.bat %temp%
c:
start /b %temp%\remove.bat


Startmenu.vbs:

Set WshShell = WScript.CreateObject("WScript.Shell")
Runstring = "%comspec% /c programs\startmenu.bat"
Return = WshShell.Run(RunString, 0, TRUE)
Set WshShell = Nothing


Remove.bat:

%temp%\devcon remove "USB\VID_0781&PID_7113"
del %temp%\devcon.exe
del %temp%\remove.bat


The vbs script launches the batch file without showing a dos window, so all you ever see is the pstart menu. I also changed it to only wait 2 seconds before dismounting, and fixed it so that it deletes the two files copied to the temp dir.

All you should have to do is change the line in remove.bat to whatever the device id for your flash drive is, and change the paths to your liking.

Good job Grant. I'm using this. It even got me to organize my USB drive a bit, creating a Documents folder on it. I added a section to close down processes likely to be running from the drive per my earlier post in this thread.

Excellent work - two quick questions though, 1st - A console window pops up, is there any way to hide it? I'm not very familiar with VBS scripts. and 2nd, My USB drive unmounts, and is removed from the "Safely Remove" list, but the light on the drive remains lit - any thoughts?

EDIT: I just tried it on my laptop, and it works as expected. (Dialog boxes instead of console windows, device ejecting as it should) I'm not sure what the issue is on my PC.

Thanks for this script. I sure will enjoy it.

The script worked not properly on my windows 2000 because unmount.exe not only unmounts my usb pen but also my usb mouse. But on the same homepage like unmount you find removedrive.exe which works better. And it ist much easier to use.

EDIT

I altered the script and insertet the kill.exe for users who want to kill other processes startet from usb pen. I use kill.exe instead of taskkill because taskkill works only with XP.
For example I kill pstart because I cannot kill my desktop-calendar (PTBSync.exe).

BEGIN SCRIPT

' Name: autorun.vbs
' found at (https://portableapps.com/node/639)
' Date: May 21, 2006
'
' originally by
' Author: Grant Emsley
' Date: Jan 28, 2006
'
' some improvements (for windows 2000 / w2k) by
' Florian Thomas Hofmann
'
' What it does:
'
' This script takes the full path/name of where the script was run from (USB Stick / USB pen drive / Memory stick), strips off everything except the drive letter and colon, and sets it to the environmental variable "portabledrive". It sets this in the Volatile Environment so it will remain set between different programs, but gets cleared when you logout/reboot.
' This allows you to make all your shortcuts and such in the format: %portabledrive%\programs\programname\program.exe
' This means that most programs that have trouble with relative paths will work
' After closing PStart the script will remove your usb pen.
' ---------------------------------------------------------
' Required Programs:
' RemoveDrive.exe (http://www.uwe-sieber.de/files/removedrive.zip)
' - This is required if you want to automatically "safely remove hardware"
' Kill.exe (http://www.pcwelt.de/downloads/heft-cd/03-05/107355/)
' - This kills like XP-tastkill in XP and also in Windows 95/98/ME/NT/2000 if you want to close some program before unmounting
' -----------------------------------------------------------

Dim objShell
Set objShell = CreateObject("WScript.Shell")
Set objFSO = CreateObject("Scripting.FileSystemObject")

' -------------------------------------------------------------
' get the drive letter
arrPath = Split(Wscript.ScriptFullName, "\")
strdriveletter = arrPath(0)

' create a collection to access the Volatile environment, then set the portabledrive
set colVolatileEnvVars = objShell.Environment("Volatile")
colVolatileEnvVars("portabledrive") = strdriveletter

' ----------------------------------------------------------
' I have a folder called "Daten" on my drive. Lets make a shortcut in "My Documents" to my portable documents folder. This way I can just click there on any save/open dialogue box.

strMyDocs = objShell.SpecialFolders("MyDocuments")
set objSLink = objShell.CreateShortcut(strMyDocs & "\Daten.lnk")
objSLink.TargetPath = strdriveletter & "\Daten"
objSlink.Save
' ----------------------------------------------------------------------------------------------------

' NOTE: if you want to run something before starting pstart, do it below this line. (guide to running programs is at the end of the script)

' Now lets run pstart, and wait for it to exit before we continue
objShell.Run strdriveletter & "\PRG\Autostart\pstart.exe", 1, TRUE

' NOTE: If you want to run something AFTER running pstart, do it below this.
' For example here you can kill other processes which use your stick
' Use this: objShell.Run strdriveletter & "\PRG\Autostart\kill.exe Program-Name", 1, TRUE
' For details on kill.exe start kill.exe /? in a dos-window

' Pstart is done, so lets clean up
' Delete the shortcut to Portable Documents
objFSO.DeleteFile(strMyDocs & "\Daten.lnk")

' Safely remove hardware
' Probably won't work if you aren't an administrator
' it WONT work if you have open files on the drive (probably a good thing)
' Warn the user that we are going to dismount the drive
Wscript.Echo "Ready to remove portable drive. Please close all programs/files on the drive, then click ok."

' First we have to change the current directory so we aren't holding the drive open.
objShell.CurrentDirectory = "C:\"
' Now we copy the file to the c drive
objFSO.CopyFile strdriveletter & "\PRG\Autostart\RemoveDrive.exe", "c:\", true
' At last we run RemoveDrive. It waits until all files are closed on the drive then removes the drive letter ans unmountes after that.
objShell.Run "c:\RemoveDrive " & strdriveletter & " -l", 1, TRUE

' Then we clean up after ourselves
objFSO.DeleteFile("C:\RemoveDrive.exe")

Wscript.Echo "Your drive should be safely removed."

Wscript.Quit

' ----------------------------------------------------------------------------------------------------
' objShell.run , ,
'
' Some good window states:
' 0 - hidden
' 1 - normal
' 2 - minimized forground
' 3 - maximized
' 7 - minimized background
'
' The last parameter takes either true or false. If true, it pauses the script and waits for it to exit before continuing. Default is false.
' ----------------------------------------------------------------------------------------------------

END SCRIPT

Hope, you enjoy this